Inserts text at insertion point or anchor point of selection
#include <GuiRichEdit.au3>
_GUICtrlRichEdit_InsertText ( $hWnd, $sText )
| $hWnd | Handle to the control |
| $sText | Text to be inserted |
| Succcess: | True. |
| Failure: | False and sets the @error flag to non-zero. |
| @error: | 101 - $hWnd is not a handle 102 - $sText = "" 103 - Cannot be set |
_GUICtrlRichEdit_AppendText, _GUICtrlRichEdit_GetText, _GUICtrlRichEdit_ReplaceText, _GUICtrlRichEdit_SetText
Search EM_SETTEXTEX in MSDN Library.
#include <GUIConstantsEx.au3>
#include <GuiRichEdit.au3>
#include <WindowsStylesConstants.au3>
Example()
Func Example()
Local $hGui, $iMsg, $idBtn_Next, $iStep = 0, $idLbl_Msg, $hRichEdit
$hGui = GUICreate("Example (" & StringTrimRight(@ScriptName, StringLen(".exe")) & ")", 320, 350, -1, -1)
$hRichEdit = _GUICtrlRichEdit_Create($hGui, "This is a test.", 10, 10, 300, 220, _
BitOR($ES_MULTILINE, $WS_VSCROLL, $ES_AUTOVSCROLL))
$idLbl_Msg = GUICtrlCreateLabel("", 10, 235, 300, 60)
$idBtn_Next = GUICtrlCreateButton("Next", 270, 310, 40, 30)
GUISetState(@SW_SHOW)
_GUICtrlRichEdit_SetText($hRichEdit, "First paragraph")
While True
$iMsg = GUIGetMsg()
Select
Case $iMsg = $GUI_EVENT_CLOSE
_GUICtrlRichEdit_Destroy($hRichEdit) ; needed unless script crashes
; GUIDelete() ; is OK too
Exit
Case $iMsg = $idBtn_Next
$iStep += 1
Switch $iStep
Case 1
_GUICtrlRichEdit_SetSel($hRichEdit, 5, 2)
Case 2
_GUICtrlRichEdit_InsertText($hRichEdit, "INSERTED_1")
GUICtrlSetData($idLbl_Msg, "Text is inserted at active point of selection")
Case 3
_GUICtrlRichEdit_GotoCharPos($hRichEdit, 20)
_GUICtrlRichEdit_InsertText($hRichEdit, "INSERTED_2")
GUICtrlSetData($idLbl_Msg, "Text is inserted at insertion point")
GUICtrlSetState($idBtn_Next, $GUI_DISABLE)
EndSwitch
EndSelect
WEnd
EndFunc ;==>Example