Sets the low and high character position of a selection
#include <GuiRichEdit.au3>
_GUICtrlRichEdit_SetSel ( $hWnd, $iAnchor, $iActive [, $bHideSel = False] )
| $hWnd | Handle to the control |
| $iAnchor | the character position of the first character to select Special value: -1 - end of text |
| $iActive | the character position of the last character to select Special value: -1 - end of text |
| $bHideSel | [optional] True to hide the selection |
| Success: | True. |
| Failure: | False and sets the @error flag to non-zero. |
| @error: | 101 - $hWnd is not a handle 102 - $iAnchor is neither a positive number nor zero nor -1 103 - $iActive is neither a positive number nor zero nor -1 104 - $bHideSel must be True or False |
The first character of the text in a control is at character position 0.
$iActive can be less than $iAnchor.
_GUICtrlRichEdit_Deselect, _GUICtrlRichEdit_GetSel, _GUICtrlRichEdit_GetSelAA, _GUICtrlRichEdit_GotoCharPos, _GUICtrlRichEdit_IsTextSelected
Search EM_EXSETSEL in MSDN Library.
#include <GUIConstantsEx.au3>
#include <GuiRichEdit.au3>
#include <WindowsStylesConstants.au3>
Global $g_idLbl_Msg, $g_hRichEdit
Example()
Func Example()
Local $hGui = GUICreate("RichEdit Get/Set Sel (v" & @AutoItVersion & ")", 320, 350, -1, -1)
$g_hRichEdit = _GUICtrlRichEdit_Create($hGui, "This is a test.", 10, 10, 300, 220, _
BitOR($ES_MULTILINE, $WS_VSCROLL, $ES_AUTOVSCROLL, $ES_NOHIDESEL))
$g_idLbl_Msg = GUICtrlCreateLabel("", 10, 235, 300, 60)
Local $idBtn_Next = GUICtrlCreateButton("Next", 270, 310, 40, 30)
GUISetState(@SW_SHOW)
Local $iMsg, $iStep = 0, $iCp1
While True
$iMsg = GUIGetMsg()
Select
Case $iMsg = $GUI_EVENT_CLOSE
_GUICtrlRichEdit_Destroy($g_hRichEdit) ; needed unless script crashes
; GUIDelete() ; is OK too
Exit
Case $iMsg = $idBtn_Next
$iStep += 1
Switch $iStep
Case 1
_GUICtrlRichEdit_SetSel($g_hRichEdit, 0, 3)
Report("1. Initial Character attributes at start of line 1 are")
Case 2
_GUICtrlRichEdit_AutoDetectURL($g_hRichEdit, True)
_GUICtrlRichEdit_AppendText($g_hRichEdit, @CRLF & "http://www.autoitscript.com")
$iCp1 = _GUICtrlRichEdit_GetFirstCharPosOnLine($g_hRichEdit, 2)
_GUICtrlRichEdit_SetSel($g_hRichEdit, $iCp1, $iCp1 + 3)
Report("2. Character attributes at start of line 2 are")
GUICtrlSetState($idBtn_Next, $GUI_DISABLE)
EndSwitch
EndSelect
WEnd
EndFunc ;==>Example
Func Report($sMsg)
Local $sRet = _GUICtrlRichEdit_GetCharAttributes($g_hRichEdit)
$sMsg = $sMsg & @CRLF & @CRLF & "Char Attributes=" & $sRet
GUICtrlSetData($g_idLbl_Msg, $sMsg)
EndFunc ;==>Report