Function Reference

_GUICtrlTreeView_SetHeight

Sets the height of the each item

#include <GuiTreeView.au3>
_GUICtrlTreeView_SetHeight ( $hWnd, $iHeight )

Parameters

$hWnd Control ID/Handle to the control
$iHeight New height of every item in pixels. Heights less than 1 will be set to 1.
If not even and the control does not have the $TVS_NONEVENHEIGHT style this value will be rounded down to the nearest even value.
If -1, the control will revert to using its default item height.

Return Value

Returns the Previous height of the items, in pixels.

Related

_GUICtrlTreeView_GetHeight

Example

#include <GUIConstantsEx.au3>
#include <GuiTreeView.au3>
#include <MsgBoxConstants.au3>
#include <WindowsStylesConstants.au3>

Example()

Func Example()
    GUICreate("TreeView Set/Get Height (v" & @AutoItVersion & ")", 400, 300)

    Local $iStyle = BitOR($TVS_EDITLABELS, $TVS_HASBUTTONS, $TVS_HASLINES, $TVS_LINESATROOT, $TVS_DISABLEDRAGDROP, $TVS_SHOWSELALWAYS, $TVS_CHECKBOXES)
    Local $idTreeView = GUICtrlCreateTreeView(2, 2, 396, 268, $iStyle, $WS_EX_CLIENTEDGE)
    GUISetState(@SW_SHOW)

    _GUICtrlTreeView_BeginUpdate($idTreeView)
    Local $aidTVi_Item[6]
    For $x = 0 To UBound($aidTVi_Item) - 1
        $aidTVi_Item[$x] = GUICtrlCreateTreeViewItem(StringFormat("[%02d] New Item", $x + 1), $idTreeView)
    Next
    _GUICtrlTreeView_EndUpdate($idTreeView)

    _GUICtrlTreeView_SetHeight($idTreeView, 30)

    MsgBox($MB_SYSTEMMODAL, "Information", StringFormat("Item Height? %s", _GUICtrlTreeView_GetHeight($idTreeView)))

    ; Loop until the user exits.
    Do
    Until GUIGetMsg() = $GUI_EVENT_CLOSE
    GUIDelete()
EndFunc   ;==>Example