Function Reference

_GUICtrlToolbar_HighlightButton

Sets the highlight state of a given button control

#include <GuiToolbar.au3>
_GUICtrlToolbar_HighlightButton ( $hWnd, $iCommandID [, $bHighlight = True] )

Parameters

$hWnd Handle to the control
$iCommandID Button command ID
$bHighlight [optional] Highlight state:
    True - Button will be highlighted
    False - Button will be unhighlighted

Return Value

Success: True.
Failure: False.

Example

#include "Extras\HelpFileInternals.au3"

#include <GUIConstantsEx.au3>
#include <GuiToolbar.au3>
#include <WinAPIConstants.au3>
#include <WindowsStylesConstants.au3>

Example()

Func Example()
    Local $hGUI, $hToolbar, $aStrings[4]
    Local Enum $e_idNew = 1000, $e_idOpen, $e_idSave, $e_idHelp

    ; Create GUI
    $hGUI = GUICreate("Toolbar", 400, 300)
    $hToolbar = _GUICtrlToolbar_Create($hGUI)
    _MemoCreate(2, 36, 396, 262, $WS_VSCROLL)
    GUISetState(@SW_SHOW)

    ; Add standard system bitmaps
    Switch _GUICtrlToolbar_GetBitmapFlags($hToolbar)
        Case 0
            _GUICtrlToolbar_AddBitmap($hToolbar, 1, -1, $IDB_STD_SMALL_COLOR)
        Case 2
            _GUICtrlToolbar_AddBitmap($hToolbar, 1, -1, $IDB_STD_LARGE_COLOR)
    EndSwitch

    ; Add strings
    $aStrings[0] = _GUICtrlToolbar_AddString($hToolbar, "&New Button")
    $aStrings[1] = _GUICtrlToolbar_AddString($hToolbar, "&Open Button")
    $aStrings[2] = _GUICtrlToolbar_AddString($hToolbar, "&Save Button")
    $aStrings[3] = _GUICtrlToolbar_AddString($hToolbar, "&Help Button")

    ; Add buttons
    _GUICtrlToolbar_AddButton($hToolbar, $e_idNew, $STD_FILENEW, $aStrings[0])
    _GUICtrlToolbar_AddButton($hToolbar, $e_idOpen, $STD_FILEOPEN, $aStrings[1])
    _GUICtrlToolbar_AddButton($hToolbar, $e_idSave, $STD_FILESAVE, $aStrings[2])
    _GUICtrlToolbar_AddButtonSep($hToolbar)
    _GUICtrlToolbar_AddButton($hToolbar, $e_idHelp, $STD_HELP, $aStrings[3])

    ; Mark Save button
    _MemoWrite("Save button Highlight State: " & _GUICtrlToolbar_IsButtonHighlighted($hToolbar, $e_idSave))
    _GUICtrlToolbar_HighlightButton($hToolbar, $e_idSave)
    _MemoWrite("Save button Highlight State: " & _GUICtrlToolbar_IsButtonHighlighted($hToolbar, $e_idSave))

    ; Loop until the user exits.
    Do
    Until GUIGetMsg() = $GUI_EVENT_CLOSE
EndFunc   ;==>Example