Function Reference

_GUICtrlTab_SetItemImage

Sets the image of a tab

#include <GuiTab.au3>
_GUICtrlTab_SetItemImage ( $hWnd, $iIndex, $iImage )

Parameters

$hWnd Control ID/Handle to the control
$iIndex 0-based item index
$iImage 0-based item image

Return Value

Success: True.
Failure: False.

Related

_GUICtrlTab_GetItemImage

Example

#include "Extras\HelpFileInternals.au3"

#include <GUIConstantsEx.au3>
#include <GuiImageList.au3>
#include <GuiTab.au3>
#include <MsgBoxConstants.au3>
#include <WinAPIGdi.au3>

Example()

Func Example()
    ; Create GUI
    Local $hGUI = GUICreate("Tab Get/Set Item Image (v" & @AutoItVersion & ")", 450, 300, 100, 100)
    Local $idTab = GUICtrlCreateTab(2, 2, 446, 266)
    _MemoMsgBoxStatus() ; Status creation

    GUISetState(@SW_SHOW)

    ; Create images
    Local $hImage = _GUIImageList_Create()
    _GUIImageList_Add($hImage, _WinAPI_CreateSolidBitmap($hGUI, 0xFF0000, 16, 16))
    _GUIImageList_Add($hImage, _WinAPI_CreateSolidBitmap($hGUI, 0x00FF00, 16, 16))
    _GUIImageList_Add($hImage, _WinAPI_CreateSolidBitmap($hGUI, 0x0000FF, 16, 16))
    _GUICtrlTab_SetImageList($idTab, $hImage)

    ; Add tabs
    _GUICtrlTab_InsertItem($idTab, 0, "Tab 0")
    _GUICtrlTab_InsertItem($idTab, 1, "Tab 1")
    _GUICtrlTab_InsertItem($idTab, 2, "Tab 2")

    ; Get/Set tab 1 image
    _GUICtrlTab_SetItemImage($idTab, 1, 1)
    _MemoMsgBox($MB_SYSTEMMODAL, "Information", "Tab 1 image index: " & _GUICtrlTab_GetItemImage($idTab, 1))

    _MemoMsgBoxStatus("", -1, $hGUI) ; no more action, wait GUI for closing

EndFunc   ;==>Example