Sets the maximum number of actions that can stored in the undo queue
#include <GuiRichEdit.au3>
_GUICtrlRichEdit_SetUndoLimit ( $hWnd, $iLimit )
| $hWnd | Handle to the control |
| $iLimit | the maximum number of actions that can be stored in the undo queue |
| Success: | True. |
| Failure: | False and sets the @error flag to non-zero. |
| @error: | 101 - $hWnd is not a handle 102 - $iLimit is neither a positive number nor zero |
To disable the Undo feature, set $iLimit to zero.
The initial value of $iLimit is 100.
_GUICtrlRichEdit_CanRedo, _GUICtrlRichEdit_CanUndo, _GUICtrlRichEdit_GetNextRedo, _GUICtrlRichEdit_Redo, _GUICtrlRichEdit_Undo
Search EM_SETUNDOLIMIT in MSDN Library.
#include <GUIConstantsEx.au3>
#include <GuiRichEdit.au3>
#include <WindowsStylesConstants.au3>
Example()
Func Example()
Local $hGui, $iMsg, $idBtn_Next, $iStep = 0, $idLbl_Msg, $hRichEdit
$hGui = GUICreate("Example (" & StringTrimRight(@ScriptName, StringLen(".exe")) & ")", 320, 350, -1, -1)
$hRichEdit = _GUICtrlRichEdit_Create($hGui, "This is a test.", 10, 10, 300, 220, _
BitOR($ES_MULTILINE, $WS_VSCROLL, $ES_AUTOVSCROLL))
$idLbl_Msg = GUICtrlCreateLabel("", 10, 235, 300, 60)
$idBtn_Next = GUICtrlCreateButton("Next", 270, 310, 40, 30)
GUISetState(@SW_SHOW)
_GUICtrlRichEdit_SetText($hRichEdit, "First paragraph")
While True
$iMsg = GUIGetMsg()
Select
Case $iMsg = $GUI_EVENT_CLOSE
_GUICtrlRichEdit_Destroy($hRichEdit) ; needed unless script crashes
; GUIDelete() ; is OK too
Exit
Case $iMsg = $idBtn_Next
$iStep += 1
Switch $iStep
Case 1
_GUICtrlRichEdit_SetUndoLimit($hRichEdit, 200)
GUICtrlSetData($idLbl_Msg, "Increased the number of actions that can stored in the undo queue from 100 to 200")
Case 2
_GUICtrlRichEdit_SetUndoLimit($hRichEdit, 0)
GUICtrlSetData($idLbl_Msg, "Undo is disabled")
GUICtrlSetState($idBtn_Next, $GUI_DISABLE)
EndSwitch
EndSelect
WEnd
EndFunc ;==>Example