Function Reference

_GUICtrlMonthCal_GetTodayStr

Retrieves the date information for the date specified as "today" in string format

#include <GuiMonthCal.au3>
_GUICtrlMonthCal_GetTodayStr ( $hWnd [, $sFormat = "%02d/%02d/%04d"] )

Parameters

$hWnd Control ID/Handle to the control
$sFormat [optional] StringFormat string used to format the date

Return Value

Returns a date in the specified format.

Related

_GUICtrlMonthCal_GetToday

Example

#include "Extras\HelpFileInternals.au3"

#include <GUIConstantsEx.au3>
#include <GuiMonthCal.au3>
#include <WindowsStylesConstants.au3>

Example()

Func Example()
    Local $idMonthCal

    ; Create GUI
    GUICreate("Month Calendar Get Today String", 400, 300)
    $idMonthCal = GUICtrlCreateMonthCal("", 4, 4, -1, -1, $WS_BORDER, 0x00000000)

    ; Create memo control
    _MemoCreate(4, 168, 392, 128, 0)
    GUISetState(@SW_SHOW)

    ; Get today
    _MemoWrite("Today: " & _GUICtrlMonthCal_GetTodayStr($idMonthCal))

    ; Loop until the user exits.
    Do
    Until GUIGetMsg() = $GUI_EVENT_CLOSE
    GUIDelete()
EndFunc   ;==>Example