Function Reference

_GUICtrlHeader_SetItemOrder

Sets the order in which the item appears

#include <GuiHeader.au3>
_GUICtrlHeader_SetItemOrder ( $hWnd, $iIndex, $iOrder )

Parameters

$hWnd Handle to the control
$iIndex 0-based item index
$iOrder 0-based item order

Return Value

Success: True.
Failure: False.

Related

_GUICtrlHeader_GetItemOrder

Example

Example 1

#include "Extras\HelpFileInternals.au3"

#include <GUIConstantsEx.au3>
#include <GuiHeader.au3>

Example()

Func Example()
    ; Create GUI
    Local $hGUI = GUICreate("Header Get/Set Item Order (v" & @AutoItVersion & ")", 450, 300, 100, 100)
    Local $hHeader = _GUICtrlHeader_Create($hGUI)
    _MemoCreate(2, 52, 444, 220)

;~  _GUICtrlHeader_SetUnicodeFormat($hHeader, True)

    GUISetState(@SW_SHOW)

    ; Add columns
    _GUICtrlHeader_AddItem($hHeader, "Column 0", 100)
    _GUICtrlHeader_AddItem($hHeader, "Column 1", 100)
    _GUICtrlHeader_AddItem($hHeader, "Column 2", 100)
    _GUICtrlHeader_AddItem($hHeader, "Column 3", 100)

    ; Set column 0 order
    _GUICtrlHeader_SetItemOrder($hHeader, 0, 3)

    ; Show column 1 order
    _MemoWrite("Column 0 order: " & _GUICtrlHeader_GetItemOrder($hHeader, 0))

    _MemoMsgBoxStatus("", -1, $hGUI) ; no more action, wait GUI for closing

EndFunc   ;==>Example

Example 2 : Header Set ItemOrder to an External process

#include "Extras\HelpFileInternals.au3"

#include <GuiHeader.au3>

Example()

Func Example()
    Local $sFromTo
    Local $hWin = _MemoRunAU3OutProcess($sFromTo) ; OK also if run in different mode

    Local $hHeader = _MemoCreateOutProcess($hWin, "SysHeader32", 1, $sFromTo)

    ; Set column 1 order
    _GUICtrlHeader_SetItemOrder($hHeader, 0, 2)

    ; Show column 0 order
    _MemoWrite("<<< Column 0 order: " & _GUICtrlHeader_GetItemOrder($hHeader, 0))

    _MemoMsgBoxStatus("", -1, $hWin) ; no more action, wait GUI for closing

EndFunc   ;==>Example