Function Reference

_GUICtrlHeader_SetItemFormat

Sets the format of the item

#include <GuiHeader.au3>
_GUICtrlHeader_SetItemFormat ( $hWnd, $iIndex, $iFormat )

Parameters

$hWnd Handle to the control
$iIndex 0-based item index
$iFormat Combination of the following format identifiers:
    $HDF_CENTER - The item's contents are centered
    $HDF_LEFT - The item's contents are left-aligned
    $HDF_RIGHT - The item's contents are right-aligned
    $HDF_BITMAP - The item displays a bitmap
    $HDF_BITMAP_ON_RIGHT - The bitmap appears to the right of text
    $HDF_OWNERDRAW - The header control's owner draws the item
    $HDF_STRING - The item displays a string
    $HDF_IMAGE - Display an image from an image list
    $HDF_RTLREADING - Text will read in the opposite direction from the text in the parent window
    $HDF_SORTDOWN - Draws a down-arrow on this item
    $HDF_SORTUP - Draws an up-arrow on this item

Return Value

Success: True.
Failure: False.

Related

_GUICtrlHeader_GetItemFormat

Example

Example 1

#include "Extras\HelpFileInternals.au3"

#include <GUIConstantsEx.au3>
#include <GuiHeader.au3>
#include <GuiImageList.au3>
#include <WinAPIGdi.au3>

Example()

Func Example()
    ; Create GUI
    Local $hGUI = GUICreate("Header Get/Set ItemFormat (v" & @AutoItVersion & ")", 450, 300, 100, 100)
    Local $hHeader = _GUICtrlHeader_Create($hGUI)
    _MemoCreate(2, 52, 444, 220)

;~  _GUICtrlHeader_SetUnicodeFormat($hHeader, True)

    GUISetState(@SW_SHOW)

    ; Create an image list with images
    Local $hImage = _GUIImageList_Create(11, 11)
    _GUIImageList_Add($hImage, _WinAPI_CreateSolidBitmap($hGUI, 0xFF0000, 11, 11))
    _GUIImageList_Add($hImage, _WinAPI_CreateSolidBitmap($hGUI, 0x00FF00, 11, 11))
    _GUIImageList_Add($hImage, _WinAPI_CreateSolidBitmap($hGUI, 0x0000FF, 11, 11))
    _GUICtrlHeader_SetImageList($hHeader, $hImage)

    ; Add columns
    _GUICtrlHeader_AddItem($hHeader, "Column 0", 100, 0, 0)
    _GUICtrlHeader_AddItem($hHeader, "Column 1", 100, 0, 1)
    _GUICtrlHeader_AddItem($hHeader, "Column 2", 100, 0, 2)
    _GUICtrlHeader_AddItem($hHeader, "Column 3", 100)

    ; Set column 0 format
    _GUICtrlHeader_SetItemFormat($hHeader, 0, BitOR($HDF_CENTER, $HDF_STRING))

    ; Show column 0 format
    _MemoWrite("Column 0 format: " & "0x" & Hex(_GUICtrlHeader_GetItemFormat($hHeader, 0)))

    Sleep(1000)

    ; Set column 0 format
    _GUICtrlHeader_SetItemFormat($hHeader, 0, BitOR($HDF_LEFT, $HDF_STRING, $HDF_IMAGE))

    ; Show column 0 format
    _MemoWrite("Column 0 format: " & "0x" & Hex(_GUICtrlHeader_GetItemFormat($hHeader, 0)))

    _MemoMsgBoxStatus("", -1, $hGUI) ; no more action, wait GUI for closing

EndFunc   ;==>Example

Example 2 : Header Set ItemFormat to an External process

#include "Extras\HelpFileInternals.au3"

#include <GuiHeader.au3>

Example()

Func Example()
    Local $sFromTo
    Local $hWin = _MemoRunAU3OutProcess($sFromTo, False) ; OK if run in different mode

    Local $hHeader = _MemoCreateOutProcess($hWin, "SysHeader32", 0, $sFromTo)

    ; Set column 0 format
    _GUICtrlHeader_SetItemFormat($hHeader, 0, BitOR($HDF_CENTER, $HDF_STRING))

    ; Show column 0 format
    _MemoWrite("Column 0 format: " & "0x" & Hex(_GUICtrlHeader_GetItemFormat($hHeader, 0)))

    _MemoMsgBoxStatus("", -1, $hWin) ; no more action, wait GUI for closing

EndFunc   ;==>Example