Function Reference

_Date_Time_DOSDateTimeToFileTime

Converts MS-DOS date and time values to a file time

#include <Date.au3>
_Date_Time_DOSDateTimeToFileTime ( $iFatDate, $iFatTime )

Parameters

$iFatDate The MS-DOS date, packed as follows:
Bits 0- 4 Day of the month (1–31)
Bits 5- 8 Month (1 = January, 2 = February, and so on)
Bits 9-15 Year offset from 1980 (add 1980 to get actual year)
$iFatTime Ths MS-DOS time, packed as follows:
Bits 0- 4 Second divided by 2
Bits 5-10 Minute (0–59)
Bits 11-15 Hour (0–23 on a 24-hour clock)

Return Value

Returns a $tagFILETIME structure that receives the converted file time.

Related

$tagFILETIME, _Date_Time_FileTimeToDOSDateTime

Example

#include "Extras\HelpFileInternals.au3"

#include <Date.au3>
#include <GUIConstantsEx.au3>
#include <WindowsStylesConstants.au3>

Example()

Func Example()
    Local $tFileTime1, $tFileTime2

    ; Create GUI
    GUICreate("Time", 400, 300)
    _MemoCreate(2, 2, 396, 296, $WS_VSCROLL)
    GUISetState(@SW_SHOW)

    ; Compare FAT Dates/Times
    $tFileTime1 = _Date_Time_DOSDateTimeToFileTime(0x3621, 0x11EF) ; 01/01/2007 02:15:30
    $tFileTime2 = _Date_Time_DOSDateTimeToFileTime(0x379F, 0x944A) ; 31/12/2007 18:34:20

    _MemoWrite("Result 1: " & _Date_Time_CompareFileTime($tFileTime1, $tFileTime2))
    _MemoWrite("Result 2: " & _Date_Time_CompareFileTime($tFileTime1, $tFileTime1))
    _MemoWrite("Result 3: " & _Date_Time_CompareFileTime($tFileTime2, $tFileTime1))

    ; Loop until the user exits.
    Do
    Until GUIGetMsg() = $GUI_EVENT_CLOSE
EndFunc   ;==>Example